Скачать: CL | DM;

Обращение к сайту   Найти похожие ветки 

← →
Ezorcist   (2006-05-08 19:17) [0]

Првиведите, пожалуйста пример кода, что бы программа обращалась к сайту (просто отметилась) - типа накрутчика. (консоль)

---

← →
Джо ©   (2006-05-09 01:08) [1]

Ну вот, примерно так, если по-быстрому.
program Project1;

{$APPTYPE CONSOLE}

uses
 Windows,
 WinInet,
 SysUtils;

var
 InetHandle,
 UrlHandle: HINTERNET;

function Read(UrlHandle: HINTERNET): string;
const
 READ_BUF_SIZE = 4096;
var
 FBuffer: array [0..READ_BUF_SIZE] of Char;
 BytesRead: Cardinal;

 function ReadBuffer: BOOL;
 begin
   Result := InternetReadFile(UrlHandle,@FBuffer,Length(FBuffer),BytesRead);
 end;

 procedure AppendResult;
 var
   I: Integer;
 begin
   for I := 0 to BytesRead-1 do
     Result := Result + FBuffer[I]
 end;

begin
 while ReadBuffer and (BytesRead <> 0) do
   AppendResult
end;

begin
 InetHandle := InternetOpen(
   "Exorcist",
   INTERNET_OPEN_TYPE_PRECONFIG,
   nil,
   nil,
   0);
 if InetHandle = nil then
   RaiseLastOSError;

 try
   UrlHandle := InternetOpenUrl(
     InetHandle,
     "http://ya.ru",
     nil,
     0,
     INTERNET_FLAG_RELOAD,
     0);
     if UrlHandle = nil then
       RaiseLastOSError;
     try
       WriteLn (Read(UrlHandle));

     finally
       InternetCloseHandle(UrlHandle)
     end;
 finally
   InternetCloseHandle(InetHandle)
 end;

 ReadLn;

end.


Только не выйдет у тебя никакого "накрутчика" :)

---

Страницы: 1 вся ветка

Скачать: CL | DM;



Память: 0.45 MB
Время: 0.025 c