Как дождатся конца работы проги, запущенной через ShellExecute ?

← →
kerkonst © (2002-09-03 11:18) [0]

Здраствуйте !
Недели две назад я уже задавал этот вопрос, и мне дали подробный ответ - текст функции из какой-то библиотеки. Но я его нигде не сохранил, а сейчас мне это снова понадобилось... Сорри...

Итак,
Как дождатся конца работы проги, запущенной через ShellExecute ?

← →
Виктор Щербаков © (2002-09-03 11:19) [1]

Используй CreateProcess.

← →
Ученик © (2002-09-03 11:23) [2]

{ Project JEDI Code Library (JCL) }

function ShellExecAndWait(const FileName: string; const Parameters: string;
const Verb: string; CmdShow: Integer): Boolean;
var
Sei: TShellExecuteInfo;
Res: LongBool;
Msg: tagMSG;

begin
FillChar(Sei, SizeOf(Sei), #0);
Sei.cbSize := SizeOf(Sei);
Sei.fMask := SEE_MASK_DOENVSUBST or SEE_MASK_FLAG_NO_UI or SEE_MASK_NOCLOSEPROCESS or
SEE_MASK_FLAG_DDEWAIT;
Sei.lpFile := PChar(FileName);
Sei.lpParameters := PCharOrNil(Parameters);
Sei.lpVerb := PCharOrNil(Verb);
Sei.nShow := CmdShow;
Result := ShellExecuteEx(@Sei);
if Result then
begin
WaitForInputIdle(Sei.hProcess, INFINITE);
while (WaitForSingleObject(Sei.hProcess, 10) = WAIT_TIMEOUT) do
begin
repeat
Res := PeekMessage(Msg, Sei.Wnd, 0, 0, PM_REMOVE);
if Res then
begin
TranslateMessage(Msg);
DispatchMessage(Msg);
end;
until (Res = False);
end;
CloseHandle(Sei.hProcess);
end;
end;

← →
kerkonst © (2002-09-03 11:28) [3]

> Ученик
Помнится, именно Вы мне в прошлый раз и ответили... Спасибо...

Требуется дополнение...

В тексте используется функция PCharOrNil.
Ее смысл понятен, так что можно и самому написать, но лучше
взять уже готовую...
Киньте, если не сложно

function PCharOrNil(const S: AnsiString): PAnsiChar;
begin
if Length(S) = 0 then
Result := nil
else
Result := PAnsiChar(S);
end;

Как дождатся конца работы проги, запущенной через ShellExecute ? Найти похожие ветки