Текущий архив: 2004.01.16;
Скачать: CL | DM;

Вниз

Вернуть активность собственной форме   Найти похожие ветки 

← →
Эли   (2004-01-02 10:42) [0]

Как вновь сделать собственное приложение активным, после того, как другое приложение стало активным?
SetForeGroundWindow(handle)почему-то не работает, если приложение обращается само к себе.

---

← →
Эли   (2004-01-02 11:54) [1]

Неужели это так трудно? Неужели надо создавать внешний экзишник, чтобы он извне вернул окну активность? Это похоже на извращение.

---

← →
TUser ©   (2004-01-02 21:35) [2]

Ловить WM_ACTIVATE, и если окно стало неактивным - вернуть ему фокус.

---

← →
Эли   (2004-01-02 21:55) [3]

Окно стало неактивным вместе со всем приложением - без всяких если. Как его сделать активным естественным - не диким способом.
Можно, к примеру, так Application.Minimize; Application.Restore...
А если не хочется всяких прыжков. Application.Restore не помогает само по себе.
Пока ничто не помогает, но решение, наверно, есть. И, скорее всего, только в одну строку.

---

← →
Ihor Osov'yak ©   (2004-01-03 13:46) [4]

try it

function ForceForegroundWindow(hwnd: THandle): boolean;
const
SPI_GETFOREGROUNDLOCKTIMEOUT = $2000;
SPI_SETFOREGROUNDLOCKTIMEOUT = $2001;
var
ForegroundThreadID: DWORD;
ThisThreadID: DWORD;
timeout: DWORD;
begin
if IsIconic(hwnd) then
ShowWindow(hwnd, SW_RESTORE);

if GetForegroundWindow = hwnd then
Result := True
else
begin
// Windows 98/2000 doesn"t want to foreground a window when some other
// window has keyboard focus
if ((Win32Platform = VER_PLATFORM_WIN32_NT) and (Win32MajorVersion > 4))
or
((Win32Platform = VER_PLATFORM_WIN32_WINDOWS) and
((Win32MajorVersion > 4) or ((Win32MajorVersion = 4) and
(Win32MinorVersion > 0)))) then
begin
// Code from Karl E. Peterson, www.mvps.org/vb/sample.htm
// Converted to Delphi by Ray Lischner
// Published in The Delphi Magazine 55, page 16
Result := False;
ForegroundThreadID := GetWindowThreadProcessID(GetForegroundWindow,
nil);
ThisThreadID := GetWindowThreadPRocessId(hwnd, nil);
if AttachThreadInput(ThisThreadID, ForegroundThreadID, True) then
begin
BringWindowToTop(hwnd); // IE 5.5 related hack
SetForegroundWindow(hwnd);
AttachThreadInput(ThisThreadID, ForegroundThreadID, False);
Result := (GetForegroundWindow = hwnd);
end;

if not Result then
begin
// Code by Daniel P. Stasinski
SystemParametersInfo(SPI_GETFOREGROUNDLOCKTIMEOUT, 0, @timeout, 0);
SystemParametersInfo(SPI_SETFOREGROUNDLOCKTIMEOUT, 0, TObject(0), SPIF_SENDCHANGE);
BringWindowToTop(hwnd); // IE 5.5 related hack
SetForegroundWindow(hWnd);
SystemParametersInfo(SPI_SETFOREGROUNDLOCKTIMEOUT, 0, TObject(timeout), SPIF_SENDCHANGE);
end;
end
else
begin
BringWindowToTop(hwnd); // IE 5.5 related hack
SetForegroundWindow(hwnd);
end;

Result := (GetForegroundWindow = hwnd);
end;
end; { ForceForegroundWindow }

---

← →
DDA ©   (2004-01-03 16:57) [5]

Опа , давно искал это

---

Страницы: 1 вся ветка

Текущий архив: 2004.01.16;
Скачать: CL | DM;

Наверх

Память: 0.47 MB
Время: 0.016 c