Главная страница
Top.Mail.Ru    Яндекс.Метрика
Текущий архив: 2005.06.14;
Скачать: CL | DM;

Вниз

Растягивание формы   Найти похожие ветки 

 
Merl   (2005-04-22 22:31) [0]

Как можно растягивать форму за края, если ее стиль утсановлен как bsNone? То есть форма без заголовка.


 
Ученик   (2005-04-22 22:51) [1]

Фрагмент :-)

procedure WMNCHitTest(var Message: TWMNCHitTest); message WM_NCHITTEST;

procedure TForm1.WMNCHitTest(var Message: TWMNCHitTest);
begin
 if Message.XPos < Left + 3 then
   Message.Result := HTLEFT
 else
   inherited
end;


 
easy ©   (2005-04-23 00:56) [2]

unit Unit1;
interface
uses
 Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
 Dialogs;
type
 TForm1 = class(TForm)
   procedure FormCreate(Sender: TObject);
 private
   { Private declarations }
   procedure WMNCHitTest(var msg: TWMNCHitTest); message wm_NCHitTest;
 public
   { Public declarations }
 end;
var
 Form1: TForm1;
implementation
{$R *.dfm}
{ TForm1 }
procedure TForm1.WMNCHitTest(var msg: TWMNCHitTest);
const
 Tolerance = 5;
var
 P: TPoint;
 OverRight: Boolean;
 OverLeft: Boolean;
 OverTop: Boolean;
 OverBottom: Boolean;
begin
 with Msg do
 begin
   P := ScreenToClient(Point(XPos, YPos));
   OverRight := Abs(P.x - Width) < Tolerance;
   OverLeft := Abs(P.x) < Tolerance;
   OverTop := Abs(P.y) < Tolerance;
   OverBottom := Abs(P.y - Height) < Tolerance;
 if OverRight then
   begin
     if OverTop then
       Result := HTTOPRIGHT
     else if OverBottom then
       Result := HTBOTTOMRIGHT
     else
       Result := HTRIGHT;
   end
   else if OverLeft then
   begin
     if OverTop then
       Result := HTTOPLEFT
     else if OverBottom then
       Result := HTBOTTOMLEFT
     else
       Result := HTLEFT;
   end
   else if OverTop then
     Result := HTTOP
   else if OverBottom then
     Result := HTBOTTOM
   else
     Result := HTCAPTION;
 end;
end;
procedure TForm1.FormCreate(Sender: TObject);
begin
  borderstyle:=bsNone;
end;
end.



Страницы: 1 вся ветка

Текущий архив: 2005.06.14;
Скачать: CL | DM;

Наверх




Память: 0.47 MB
Время: 0.025 c
1-1117430496
vvllaadd
2005-05-30 09:21
2005.06.14
Перенос текста в BitBtn ...


14-1116866445
NikNet
2005-05-23 20:40
2005.06.14
Где скачать весь DevExpress или хотябы TreeView,ToolBar?


1-1117344094
VasilijOrlov
2005-05-29 09:21
2005.06.14
как мне сделать, чтобы пользователь щелкнул, изменил, закрыл и вс


3-1115272204
sashuly
2005-05-05 09:50
2005.06.14
поиск в подчиненной таблице


1-1117282425
PIF
2005-05-28 16:13
2005.06.14
Компиляция res файла при старте приложения