Скачать: CL | DM;

Image   Найти похожие ветки 

← →
Максо   (2006-05-01 13:16) [0]

у меня есть три файла для кнопки,при наведении одна,при нажатии другая....
вродь все ок,но как лучше сделать чтобы при наведении image менялся? т.е. картинка делаю mousemove а как обратно,если делать на mousemove на форме то image постоянно мигает
подскажите

---

← →
Virgo_Style ©   (2006-05-01 13:36) [1]

CM_MouseEnter / Leave, аналогично тому, как это сделано в TLabel ?

---

← →
Loginov Dmitry ©   (2006-05-01 13:43) [2]

В данном случае самый простой выход - создать новый компонент.

unit MyExImageUnit;

interface

uses
 Windows, Messages, SysUtils, Classes, Controls, ExtCtrls;

type
 TMyExImage = class(TImage)
 private
   { Private declarations }
   FOnMouseLeave: TNotifyEvent;
   FOnMouseEnter: TNotifyEvent;

   procedure CMMouseEnter(var Message: TMessage); message CM_MOUSEENTER;
   procedure CMMouseLeave(var Message: TMessage); message CM_MOUSELEAVE;
 protected
   { Protected declarations }
 public
   { Public declarations }
 published
   { Published declarations }
   property OnMouseEnter: TNotifyEvent read FOnMouseEnter write FOnMouseEnter;
   property OnMouseLeave: TNotifyEvent read FOnMouseLeave write FOnMouseLeave;
 end;

procedure Register;

implementation

procedure Register;
begin
 RegisterComponents(Samples", [TMyExImage]);
end;

/////////////////////////////////////////////////////////////////
procedure TMyExImage.CMMouseEnter(var Message: TMessage);
begin
 inherited;
 if Assigned(FOnMouseEnter) then
   FOnMouseEnter(Self);
end;

procedure TMyExImage.CMMouseLeave(var Message: TMessage);
begin
 inherited;
 if Assigned(FOnMouseLeave) then
   FOnMouseLeave(Self);
end;
////////////////////////////////////////////////////////////////////

end.

---

← →
Максо   (2006-05-01 21:02) [3]

спасиб

---

Страницы: 1 вся ветка

Скачать: CL | DM;



Память: 0.45 MB
Время: 0.024 c