Текущий архив: 2003.01.27;
Скачать: CL | DM;

Вниз

MDIForm   Найти похожие ветки 

← →
Novice2   (2003-01-17 16:21) [0]

Подскажите, кто может, как убрать (чтобы не появлялись вообще) скроллбары в MDI форме при перемещении MDI чилдных форм ?

---

← →
Skier ©   (2003-01-17 16:28) [1]

Не поможет ?
HorzScrollBar.Visible := False;
VertScrollBar.Visible := False;

---

← →
Бук   (2003-01-17 16:34) [2]

Не-а. Не срабатывает. Такая же ерунда и у меня. Стоит дочерней форме выйти за границы - появляются бары

---

← →
Delirium^.Tremens ©   (2003-01-17 16:37) [3]

Пора здесь уже отдельную конфу открывать MDI :-)

---

← →
Novice2   (2003-01-17 16:55) [4]

2 Delirium^.Tremens © (17.01.03 16:37)
Пора здесь уже отдельную конфу открывать MDI :-)

А толк будет ? Ж;-)

Кстати, в ворде все нормально

---

← →
Игорь Шевченко ©   (2003-01-17 16:59) [5]

{ Избавление от ScrollBar"ов в MDI-форме. (С) Peter Below (TeamB) }
{ Не надо VCL переписывать :-) }

unit MainForm;

interface

uses
Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
Menus;

type
TfMain = class(TForm)
MainMenu1: TMainMenu;
Newchild1: TMenuItem;
Newchild2: TMenuItem;
procedure Newchild2Click(Sender: TObject);
procedure FormCreate(Sender: TObject);
private
{ Private declarations }
public
{ Public declarations }
end;

var
fMain: TfMain;

implementation

uses ChildForm;

{$R *.DFM}

procedure TfMain.Newchild2Click(Sender: TObject);
begin
with TfChild.Create(Application) do
Show();
end;

function ClientWindowProc( wnd: HWND; msg: Cardinal; wparam, lparam: Integer ): Integer; stdcall;
var
f: Pointer;
begin
f := Pointer( GetWindowLong( wnd, GWL_USERDATA ));
case msg of
WM_NCCALCSIZE:
if ( GetWindowLong( wnd, GWL_STYLE ) and
(WS_HSCROLL or WS_VSCROLL)) <> 0 then
SetWindowLong( wnd, GWL_STYLE, GetWindowLong( wnd, GWL_STYLE )
and not (WS_HSCROLL or WS_VSCROLL));
end;
Result := CallWindowProc( f, wnd, msg, wparam, lparam );
end;

procedure TfMain.FormCreate(Sender: TObject);
begin
if ClientHandle <> 0 then begin
if GetWindowLong( ClientHandle, GWL_USERDATA ) <> 0 then
Exit; {cannot subclass client window, userdata already in use}
SetWindowLong(ClientHandle, GWL_USERDATA, SetWindowLong( ClientHandle,
GWL_WNDPROC, integer( @ClientWindowProc)));
end;

end;

end.


---

← →
Novice2   (2003-01-17 17:39) [6]

Большое спасибо Игорю Шевченко © !
Работает !

---

Страницы: 1 вся ветка

Текущий архив: 2003.01.27;
Скачать: CL | DM;

Наверх

Память: 0.47 MB
Время: 0.024 c