Главная страница
Top.Mail.Ru    Яндекс.Метрика
Текущий архив: 2002.07.15;
Скачать: CL | DM;

Вниз

наследник от TPanel с onmouseleave   Найти похожие ветки 

 
spacerex ©   (2002-06-27 17:15) [0]

Как создать Свой наследник от TPanel с onmouseleave


 
Игорь Шевченко ©   (2002-06-27 17:17) [1]

Сам наследник:

unit MouseSensitivePanel;

interface
uses
ExtCtrls, Controls, Classes, Messages;

type
TMouseSensitivePanel = class(TPanel)
private
FOnMouseLeave: TNotifyEvent;
FOnMouseEnter: TNotifyEvent;
procedure CMMouseEnter (var Message : TMessage); message CM_MOUSEENTER;
procedure CMMouseLeave (var Message : TMessage); message CM_MOUSELEAVE;
procedure DoMouseEnter; dynamic;
procedure DoMouseLeave; dynamic;
published
property OnMouseEnter : TNotifyEvent read FOnMouseEnter write FOnMouseEnter;
property OnMouseLeave : TNotifyEvent read FOnMouseLeave write FOnMouseLeave;
end;


implementation

{ TMouseSensitivePanel }

procedure TMouseSensitivePanel.CMMouseEnter(var Message: TMessage);
begin
inherited;
DoMouseEnter();
end;

procedure TMouseSensitivePanel.CMMouseLeave(var Message: TMessage);
begin
inherited;
DoMouseLeave();
end;

procedure TMouseSensitivePanel.DoMouseEnter;
begin
if Assigned(FOnMouseEnter) then
FOnMouseEnter(Self);
end;

procedure TMouseSensitivePanel.DoMouseLeave;
begin
if Assigned(FOnMouseLeave) then
FOnMouseLeave(Self);
end;

end.


Пример использования:

unit main;

interface

uses
Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
MouseSensitivePanel, ExtCtrls;

type
TForm1 = class(TForm)
Panel1: TPanel;
procedure FormCreate(Sender: TObject);
private
FPanel : TMouseSensitivePanel;
procedure PanelMouseEnter (Sender : TObject);
procedure PanelMouseLeave (Sender : TObject);
end;

var
Form1: TForm1;

implementation

{$R *.DFM}

procedure TForm1.PanelMouseEnter(Sender: TObject);
begin
(Sender AS TPanel).Color := clRed;
end;

procedure TForm1.PanelMouseLeave(Sender: TObject);
begin
(Sender AS TPanel).Color := clBtnFace;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
FPanel := TMouseSensitivePanel.Create(Self);
with FPanel do begin
Parent := Self;
BoundsRect := Panel1.BoundsRect;
OnMouseEnter := PanelMouseEnter;
OnMouseLeave := PanelMouseLeave;
end;
end;

end.




Страницы: 1 вся ветка

Текущий архив: 2002.07.15;
Скачать: CL | DM;

Наверх




Память: 0.47 MB
Время: 0.011 c
1-47399
lex1
2002-06-27 15:31
2002.07.15
Визуализация контролов формы.


3-47144
Jony
2002-06-18 16:03
2002.07.15
Работа с картинками *.jpg в Delphi/MS SQL


1-47562
Igorek
2002-06-24 23:43
2002.07.15
TypInfo.pas - недокументированные возможности


6-47653
Lizard
2002-05-02 22:12
2002.07.15
Как обойти ошибку ?


1-47369
race1
2002-07-01 13:00
2002.07.15
component