Текущий архив: 2004.12.19;
Скачать: CL | DM;

Вниз

Включение графики в браузере   Найти похожие ветки 

← →
Артем Владимирович   (2004-12-04 11:54) [0]

Уважаемые Мастера!Как проверить включено ли у браузера отображение графики(сервис-свойства обозревателя-дополнительно-отображать рисунки)?

В случае отключененного состояния как включить на время работы программы? Это нужно для WebBrowser-а.

---

← →
Артем Владимирович   (2004-12-04 16:33) [1]

Есть идеи?

---

← →
Jel ©   (2004-12-04 17:02) [2]

Проверять в реестре?

HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Internet Explorer\AdvancedOptions

---

← →
easy ©   (2004-12-04 17:47) [3]

unit Unit1;

interface

uses
 Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
 Dialogs, OleCtrls, SHDocVw, ActiveX;

type TWebBrowser1 = class(TWebBrowser, IDispatch)
 protected
   function IDispatch.Invoke = Invoke;
   function Invoke(DispID: Integer; const IID: TGUID; LocaleID: Integer;
     Flags: Word; var Params; VarResult, ExcepInfo, ArgErr: Pointer): HResult;
     stdcall;
 end;

type
 TForm1 = class(TForm)
   procedure FormCreate(Sender: TObject);
   procedure FormDestroy(Sender: TObject);
 private
   { Private declarations }
   wb: TWebBrowser1;
 public
   { Public declarations }
 end;

var
 Form1: TForm1;

implementation

{$R *.dfm}

{ TWebBrowser1 }

function TWebBrowser1.Invoke(DispID: Integer; const IID: TGUID;
 LocaleID: Integer; Flags: Word; var Params; VarResult, ExcepInfo,
 ArgErr: Pointer): HResult;
const
 DISPID_AMBIENT_DLCONTROL = -5512;
 DLCTL_DLIMAGES = $00000010;
begin
 if (Flags and DISPATCH_PROPERTYGET <> 0) and (VarResult <> nil) then
 begin
   Result := S_OK;
   case DispID of DISPID_AMBIENT_DLCONTROL:
       PVariant(VarResult)^ := Integer(DLCTL_DLIMAGES);
   else
     Result := DISP_E_MEMBERNOTFOUND;
   end;
 end else
   result := inherited invoke(dispid, iid, localeid, flags, params, varresult,
     ExcepInfo, argerr);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
 wb := TWebBrowser1.Create(self);
 TControl(wb).Parent := form1;
 wb.Align := alClient;
 wb.Navigate("http://ya.ru");
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
 wb.Free;
end;

end.

---

Страницы: 1 вся ветка

Текущий архив: 2004.12.19;
Скачать: CL | DM;

Наверх

Память: 0.47 MB
Время: 0.025 c