Текущий архив: 2004.04.04;
Скачать: CL | DM;

Вниз

OnMouseMove   Найти похожие ветки 

← →
Sirruf ©   (2004-03-16 17:11) [0]

Хочу отследить событие TForm.OnMouseMove, а на форме лежит Groupbox, и когда мышка над ним, событие формы не срабатывает. А у групбокса ваще событий нет. Че делать?

---

← →
serge35   (2004-03-16 17:25) [1]

На прошлой неделе был похожий вопрос. Попробуй найти эту конфу.
Смысл в определении кординат мыши и над какой компонентой она находится.

---

← →
Magisimus ©   (2004-03-16 18:20) [2]

просто у groupbox"а onmousemove сделай тем же что и у tform

---

← →
serge ©   (2004-03-16 18:30) [3]

Используй это для своей формы:


Чтобы отслеживать события во всей Windows используют ловушку (hook). Для этого нужно создать функцию, обрабатывающую сообщения. Адрес этой функции нужно передать Windows при установке ловушки.
Эта программа определяет, нажата ли левая или правая кнопка мыши, при движении мыши определяет ее координаты. При нажатии на клавишу клавиатуры определяется, что это за клавиша.

var
 HookHandle: hHook;

function HookProc(Code: integer; WParam: word; LParam: Longint): Longint; stdcall;
var
 msg: PEVENTMSG;
 key: integer;
begin
 if Code >= 0 then begin
   result := 0;
   msg := Pointer(LParam);
   with Form1 do
     case msg.message of
       WM_MOUSEMOVE: Caption := IntToStr(msg.ParamL) + #32 + IntToStr(msg.ParamH);
       WM_LBUTTONDOWN: CheckBox1.Checked := true;
       WM_LBUTTONUP: CheckBox1.Checked := false;
       WM_RBUTTONDOWN: CheckBox2.Checked := true;
       WM_RBUTTONUP: CheckBox2.Checked := false;
       WM_KEYUP: CheckBox3.Checked := false;
       WM_KEYDOWN: begin
         CheckBox3.Checked := true;
         key := msg.paramL and 255;
         if key in [48..57, 65..90]
           then Edit1.Text := Edit1.Text + chr(key);
       end;
     end;
 end else
   result := CallNextHookEx(HookHandle, code, WParam, LParam);
end;
procedure TForm1.FormCreate(Sender: TObject);
begin
 Form1.FormStyle := fsStayOnTop;
 CheckBox1.Enabled := false;
 CheckBox1.Caption := "left button";
 CheckBox2.Enabled := false;
 CheckBox2.Caption := "right button";
 CheckBox3.Enabled := false;
 CheckBox3.Caption := "keyboard";
 HookHandle := SetWindowsHookEx(WH_JOURNALRECORD, @HookProc, HInstance, 0);
 Edit1.Text := "";
 Edit1.Enabled := false;
end;
procedure TForm1.FormDestroy(Sender: TObject);
begin
 if HookHandle > 0 then
   UnhookWindowsHookEx(HookHandle);
end;



---

← →
Игорь Шевченко ©   (2004-03-16 18:44) [4]

unit main;

interface
uses
 Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
 StdCtrls;

type
 TfMain = class(TForm)
   Label1: TLabel;
   GroupBox1: TGroupBox;
   Edit1: TEdit;
   Button1: TButton;
   procedure FormCreate(Sender: TObject);
   procedure FormMouseMove(Sender: TObject; Shift: TShiftState; X,
     Y: Integer);
 end;

var
 fMain: TfMain;

implementation

{$R *.DFM}

type
 TControlAccess = class(TControl);

procedure TfMain.FormCreate(Sender: TObject);
var
 I: Integer;
begin
 for I:=0 to Pred(ComponentCount) do
   if Components[I] is TControl then
     TControlAccess(Components[I]).OnMouseMove := FormMouseMove;
end;

procedure TfMain.FormMouseMove(Sender: TObject; Shift: TShiftState; X,
 Y: Integer);
begin
 Label1.Caption := Format("Mouse is over %s(%s), X,Y=(%d,%d)",
   [(Sender as TComponent).Name, Sender.ClassName, X, Y]);
end;

end.


---

← →
Игорь Шевченко ©   (2004-03-17 10:27) [5]

Некоторая модификация, в которой X и Y пересчитываются в координаты относительно формы, вне зависимости от того, над каким контролом на форме находится курсор мыши.


type
 TControlAccess = class(TControl);

procedure TfMain.FormCreate(Sender: TObject);
var
 I: Integer;
begin
 for I:=0 to Pred(ComponentCount) do
   if Components[I] is TControl then
     TControlAccess(Components[I]).OnMouseMove := FormMouseMove;
end;

procedure TfMain.FormMouseMove(Sender: TObject; Shift: TShiftState; X,
 Y: Integer);
var
 P: TPoint;
 WinControl: TWinControl;
begin
 P := Point(X, Y);
 if Sender is TWinControl then
   WinControl := TWinControl(Sender)
 else begin
   WinControl := (Sender as TControl).Parent;
   Inc(P.X, TControl(Sender).Left);
   Inc(P.Y, TControl(Sender).Top);
 end;
 MapWindowPoints(WinControl.Handle, Handle, P, 1);
 X := P.X;
 Y := P.Y;
 Label1.Caption := Format("Mouse is over %s(%s), X,Y=(%d,%d)",
   [(Sender as TComponent).Name, Sender.ClassName, X, Y]);
end;


---

Страницы: 1 вся ветка

Текущий архив: 2004.04.04;
Скачать: CL | DM;

Наверх

Память: 0.48 MB
Время: 0.027 c