Как определить кем создан файл?

← →
NAU (2002-09-04 05:48) [0]

Подскажите, как определить имя пользователя создавшего файл, владельца файла?

← →
Ученик (2002-09-04 09:30) [1]

function GetFileOwner(const FileName : string; var Domain, UserName : string) : Boolean;
var
bOwnerDefaulted : Bool;
psd : PSECURITY_DESCRIPTOR;
sid : PSID;
dwDomainSize, dwUserNameSize, dwSize, dwUse : DWord;
begin
Result := False;
if not GetFileSecurity(PChar(FileName), OWNER_SECURITY_INFORMATION, nil,
0, dwSize) and (GetLastError = ERROR_INSUFFICIENT_BUFFER) then begin
psd := HeapAlloc(GetProcessHeap, 8, dwSize);
if psd <> nil then try
if GetFileSecurity(PChar(FileName), OWNER_SECURITY_INFORMATION,
psd, dwSize, dwSize) and GetSecurityDescriptorOwner(psd, sid, bOwnerDefaulted) then begin
dwUserNameSize := 0;
dwDomainSize := 0;
if not LookupAccountSid(nil, sid, nil, dwUserNameSize, nil, dwDomainSize, dwUse) and
(GetLastError = ERROR_INSUFFICIENT_BUFFER) then begin
SetLength(Domain, dwDomainSize);
SetLength(UserName, dwUserNameSize);
Result := LookupAccountSid(nil, sid, PChar(UserName), dwUserNameSize,
PChar(Domain), dwDomainSize, dwUse);
if Result then begin
SetLength(Domain, dwDomainSize);
SetLength(UserName, dwUserNameSize)
end
end
end
finally
HeapFree(GetProcessHeap, 0, psd)
end
end
end;

Как определить кем создан файл? Найти похожие ветки